dhcpcd-qt: Add support for KDE5 Notifications
[dhcpcd-ui] / src / dhcpcd-qt / dhcpcd-qt.pro
1 CONFIG+=                qt c++11 debug
2 QT+=                    gui core widgets
3 QMAKE_CXXFLAGS+=        -std=c++11 -O2
4
5 HEADERS=                dhcpcd-qt.h dhcpcd-about.h dhcpcd-preferences.h \
6                         dhcpcd-wi.h dhcpcd-ifmenu.h \
7                         dhcpcd-ssid.h \
8                         dhcpcd-ssidmenu.h dhcpcd-ssidmenuwidget.h \
9                         dhcpcd-ipv4validator.h dhcpcd-singleton.h
10 SOURCES=                main.cpp dhcpcd-qt.cpp dhcpcd-about.cpp \
11                         dhcpcd-preferences.cpp dhcpcd-wi.cpp \
12                         dhcpcd-ifmenu.cpp \
13                         dhcpcd-ssid.cpp \
14                         dhcpcd-ssidmenu.cpp dhcpcd-ssidmenuwidget.cpp \
15                         dhcpcd-ipv4validator.cpp dhcpcd-singleton.cpp
16
17 INCLUDEPATH+=           ../../
18 INCLUDEPATH+=           ../libdhcpcd/
19
20 LIBS+=                  -L../libdhcpcd ../libdhcpcd/libdhcpcd.a
21
22 has_libintl {
23         LIBS +=         -lintl
24 }
25
26 has_libkdeui {
27         LIBS+=          -lkdeui
28         DEFINES+=       NOTIFY
29         INSTALLS+=      notifyrc
30 }
31
32 QMAKE_CLEAN+=           ${TARGET}
33
34 isEmpty(PREFIX) {
35         PREFIX=         /usr/local
36 }
37 isEmpty(SYSCONFDIR) {
38         SYSCONFDIR=     $$PREFIX/etc
39 }
40 isEmpty(MANDIR) {
41         MANDIR=         $$PREFIX/share/man
42 }
43
44 target.path=            $$PREFIX/bin
45
46 man8.path=              $$MANDIR/man8
47 man8.files=             dhcpcd-qt.8
48
49 desktop.path=           $$SYSCONFDIR/xdg/autostart
50 desktop.files=          dhcpcd-qt.desktop
51
52 notifyrc.path=          $$PREFIX/share/apps/dhcpcd-qt
53 notifyrc.files=         dhcpcd-qt.notifyrc
54
55 INSTALLS+=              target man8 desktop