Display the PSK entry box near the mouse.
[dhcpcd-ui] / src / dhcpcd-qt / dhcpcd-qt.pro
1 CONFIG+=                qt gui c++11 debug
2 QMAKE_CXXFLAGS+=        -std=c++11 -O2
3
4 HEADERS=                dhcpcd-qt.h dhcpcd-about.h dhcpcd-preferences.h \
5                         dhcpcd-wi.h dhcpcd-ifmenu.h \
6                         dhcpcd-ssid.h \
7                         dhcpcd-ssidmenu.h dhcpcd-ssidmenuwidget.h \
8                         dhcpcd-ipv4validator.h
9 SOURCES=                main.cpp dhcpcd-qt.cpp dhcpcd-about.cpp \
10                         dhcpcd-preferences.cpp dhcpcd-wi.cpp \
11                         dhcpcd-ifmenu.cpp \
12                         dhcpcd-ssid.cpp \
13                         dhcpcd-ssidmenu.cpp dhcpcd-ssidmenuwidget.cpp \
14                         dhcpcd-ipv4validator.cpp
15
16 INCLUDEPATH+=           ../../
17 INCLUDEPATH+=           ../libdhcpcd/
18
19 LIBS+=                  -L../libdhcpcd ../libdhcpcd/libdhcpcd.a
20
21 build_bgscan {
22         DEFINES+=       BG_SCAN
23 }
24
25 has_libintl {
26         LIBS +=         -lintl
27 }
28
29 has_libkdeui {
30         LIBS+=          -lkdeui
31         DEFINES+=       NOTIFY
32         INSTALLS+=      notifyrc
33 }
34
35 QMAKE_CLEAN+=           ${TARGET}
36
37 isEmpty(PREFIX) {
38         PREFIX=         /usr/local
39 }
40 isEmpty(SYSCONFDIR) {
41         SYSCONFDIR=     $$PREFIX/etc
42 }
43 isEmpty(MANDIR) {
44         MANDIR=         $$PREFIX/share/man
45 }
46
47 target.path=            $$PREFIX/bin
48
49 man8.path=              $$MANDIR/man8
50 man8.files=             dhcpcd-qt.8
51
52 desktop.path=           $$PREFIX/share/applications
53 desktop.files=          dhcpcd-qt.desktop
54
55 notifyrc.path=          $$PREFIX/share/apps/dhcpcd-qt
56 notifyrc.files=         dhcpcd-qt.notifyrc
57
58 INSTALLS+=              target man8 desktop