roy.marples.name Git - dhcpcd-ui/blob - src/dhcpcd-qt/dhcpcd-qt.pro

   1 CONFIG+=                qt gui c++11 debug
   2 QMAKE_CXXFLAGS+=        -std=c++11 -O2
   3
   4 HEADERS=                dhcpcd-qt.h dhcpcd-about.h dhcpcd-preferences.h \
   5                         dhcpcd-wi.h dhcpcd-ifmenu.h dhcpcd-ssidmenu.h \
   6                         dhcpcd-ipv4validator.h
   7 SOURCES=                main.cpp dhcpcd-qt.cpp dhcpcd-about.cpp \
   8                         dhcpcd-preferences.cpp dhcpcd-wi.cpp \
   9                         dhcpcd-ifmenu.cpp dhcpcd-ssidmenu.cpp \
  10                         dhcpcd-ipv4validator.cpp
  11
  12 INCLUDEPATH+=           ../../
  13 INCLUDEPATH+=           ../libdhcpcd/
  14
  15 LIBS+=                  -L../libdhcpcd ../libdhcpcd/libdhcpcd.a
  16
  17 has_libintl {
  18         LIBS +=         -lintl
  19 }
  20
  21 QMAKE_CLEAN+=           ${TARGET}
  22
  23 isEmpty(PREFIX) {
  24         PREFIX=         /usr/local
  25 }
  26 isEmpty(MANDIR) {
  27         MANDIR=         $$PREFIX/share/man
  28 }
  29
  30 target.path=            $$PREFIX/bin
  31
  32 man8.path=              $$MANDIR/man8
  33 man8.files=             dhcpcd-qt.8
  34
  35 desktop.path=           $$PREFIX/share/applications
  36 desktop.files=          dhcpcd-qt.desktop
  37
  38 autostart.path=         $$PREFIX/share/autostart
  39 autostart.files=        dhcpcd-qt.desktop
  40
  41 INSTALLS+=              target man8 desktop autostart