Add a singleton class to ensure that dhcpcd-qt runs once per user per display.
[dhcpcd-ui] / src / dhcpcd-qt / dhcpcd-qt.pro
1 CONFIG+=                qt gui c++11 debug
2 QMAKE_CXXFLAGS+=        -std=c++11 -O2
3
4 HEADERS=                dhcpcd-qt.h dhcpcd-about.h dhcpcd-preferences.h \
5                         dhcpcd-wi.h dhcpcd-ifmenu.h \
6                         dhcpcd-ssid.h \
7                         dhcpcd-ssidmenu.h dhcpcd-ssidmenuwidget.h \
8                         dhcpcd-ipv4validator.h dhcpcd-singleton.h
9 SOURCES=                main.cpp dhcpcd-qt.cpp dhcpcd-about.cpp \
10                         dhcpcd-preferences.cpp dhcpcd-wi.cpp \
11                         dhcpcd-ifmenu.cpp \
12                         dhcpcd-ssid.cpp \
13                         dhcpcd-ssidmenu.cpp dhcpcd-ssidmenuwidget.cpp \
14                         dhcpcd-ipv4validator.cpp dhcpcd-singleton.cpp
15
16 INCLUDEPATH+=           ../../
17 INCLUDEPATH+=           ../libdhcpcd/
18
19 LIBS+=                  -L../libdhcpcd ../libdhcpcd/libdhcpcd.a
20
21 has_libintl {
22         LIBS +=         -lintl
23 }
24
25 has_libkdeui {
26         LIBS+=          -lkdeui
27         DEFINES+=       NOTIFY
28         INSTALLS+=      notifyrc
29 }
30
31 QMAKE_CLEAN+=           ${TARGET}
32
33 isEmpty(PREFIX) {
34         PREFIX=         /usr/local
35 }
36 isEmpty(SYSCONFDIR) {
37         SYSCONFDIR=     $$PREFIX/etc
38 }
39 isEmpty(MANDIR) {
40         MANDIR=         $$PREFIX/share/man
41 }
42
43 target.path=            $$PREFIX/bin
44
45 man8.path=              $$MANDIR/man8
46 man8.files=             dhcpcd-qt.8
47
48 desktop.path=           $$SYSCONFDIR/xdg/autostart
49 desktop.files=          dhcpcd-qt.desktop
50
51 notifyrc.path=          $$PREFIX/share/apps/dhcpcd-qt
52 notifyrc.files=         dhcpcd-qt.notifyrc
53
54 INSTALLS+=              target man8 desktop